[[MDL_START]]

Public Const aantal_teams            As Integer = 4
Public Const aantal_spelers_per_team As Integer = 4
Public Const aantal_spelers          As Integer = 16
Public Const aantal_rijen            As Integer = 4
Public Const aantal_kolommen         As Integer = 4
Public Const aantal_vakken           As Integer = 16

Public cpt_ui                        As New cls_cpt_ui
Public subcpt_ui                     As New cls_subcpt_ui
Public tbl_speler                    As New cls_tbl_speler
Public tbl_speelbord                 As New cls_tbl_speelbord
Public status                        As New cls_status
Public speelbord                     As New frm_speelbord
Public pion                          As New frm_pion

Public Sub Main()
    Call speelbord.Show
    Call cpt_ui.srvc_start_nieuw_spel
End Sub


[[FRM_VOEG_SPELER_TOE]]

Private Sub Form_Load()
    For speler_nummer = 1 To aantal_spelers
        im_pion(speler_nummer).Picture = pion.im_pion(speler_nummer).Picture
    Next
End Sub

Private Sub knp_voeg_speler_toe_Click()
    Dim speler(aantal_spelers) As String
    
    For speler_nummer = 1 To aantal_spelers
        speler(speler_nummer) = tb_naam_speler(speler_nummer).Text
    Next
    Call cpt_ui.srvc_voeg_speler_toe(speler())
    Unload Me
End Sub


[[FRM_VOEG_SYSTEEM_TOE]]

Private speler_heeft_systeem_in_vak(aantal_spelers) As Boolean

Private Sub Form_Load()
    Call subcpt_ui.srvc_speler_heeft_systeem_in_vak( _
        status.vak_nummer, _
        speler_heeft_systeem_in_vak())
    lbl_gebied.Caption = "gebied " & _
        speelbord.lbl_vak_nummer(status.vak_nummer).Caption

    For speler_nummer = 1 To tbl_speler.aantal_rijen
        im_pion(speler_nummer).Picture = _
            pion.im_pion(tbl_speler.rij(CLng(speler_nummer)).pion_nummer).Picture
        im_pion_geselecteerd(speler_nummer).Picture = _
            im_pion(speler_nummer).Picture
        im_pion_geselecteerd(speler_nummer).Visible = _
            speler_heeft_systeem_in_vak(speler_nummer)
        If speler_heeft_systeem_in_vak(speler_nummer) Then _
            Call disable_team(tbl_speler.rij(CLng(speler_nummer)).team_nummer)
    Next
End Sub

Private Sub Form_Unload(cancel As Integer)
    status.vak_nummer = 0
End Sub

Private Sub disable_team(ByVal team_nummer As Integer)
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        If tbl_speler.rij(CLng(speler_nummer)).team_nummer = team_nummer Then _
            im_pion(speler_nummer).Enabled = False
    Next
End Sub

Private Sub enable_team(ByVal team_nummer As Integer)
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        If tbl_speler.rij(CLng(speler_nummer)).team_nummer = team_nummer Then _
            im_pion(speler_nummer).Enabled = True
    Next
End Sub

Private Sub im_pion_Click(speler_nummer As Integer)
    im_pion_geselecteerd(speler_nummer).Visible = True
    im_pion_geselecteerd(speler_nummer).Enabled = True
    Call disable_team(tbl_speler.rij(speler_nummer).team_nummer)
End Sub

Private Sub im_pion_geselecteerd_Click(speler_nummer As Integer)
    im_pion_geselecteerd(speler_nummer).Visible = False
    im_pion_geselecteerd(speler_nummer).Enabled = False
    Call enable_team(tbl_speler.rij(speler_nummer).team_nummer)
End Sub

Private Sub knp_voeg_systeem_toe_Click()
    Dim nieuw_systeem(aantal_spelers) As Integer
    
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        If im_pion_geselecteerd(speler_nummer).Visible _
            And Not speler_heeft_systeem_in_vak(speler_nummer) Then _
            nieuw_systeem(speler_nummer) = 1
        If Not im_pion_geselecteerd(speler_nummer).Visible _
            And speler_heeft_systeem_in_vak(speler_nummer) Then _
            nieuw_systeem(speler_nummer) = -1
    Next
    Call cpt_ui.srvc_voeg_systeem_toe(status.vak_nummer, nieuw_systeem())
    status.vak_nummer = 0
    Unload Me
End Sub


[[FRM_SPEELBORD]]

Private Sub Form_Load()
    Me.WindowState = 2
    For speler_nummer = 1 To aantal_spelers
        Me.tb_naam_speler(speler_nummer).Visible = False
        Me.im_pion_speler(speler_nummer).Visible = False
        Me.tb_marktaandeel_speler(speler_nummer).Visible = False
    Next
    Me.lbl_stap(1).BackStyle = 1
    For stap_nummer = 1 To 6
        Me.lbl_stap(stap_nummer).BackColor = 65280
    Next
    Call Me.disable_toevoegen_systeem
End Sub

Private Sub Form_Unload(cancel As Integer)
    If MsgBox("wilt u de applicatie afsluiten?", 1, "IT-governance game") = vbOK Then
        Unload pion
    Else
        cancel = 1
    End If
End Sub

Public Sub initialiseer()
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        Me.tb_naam_speler(speler_nummer).Visible = True
        Me.im_pion_speler(speler_nummer).Visible = True
        Me.tb_marktaandeel_speler(speler_nummer).Visible = True
        Me.tb_naam_speler(speler_nummer).Text = _
            tbl_speler.rij(CLng(speler_nummer)).speler_naam
        Me.im_pion_speler(speler_nummer).Picture = _
            pion.im_pion(tbl_speler.rij(CLng(speler_nummer)).pion_nummer).Picture
    Next
End Sub

Public Sub refresh_me()
    Dim marktaandeel_speler(aantal_spelers) As Double
    Dim score_volgorde(aantal_spelers)      As Integer
    Dim aantal_systemen                     As Integer
    Dim huidig_speelbord                    As cls_rij_speelbord
    Dim volg_nummer                         As Integer
    Dim systeem_is_nieuw                    As Boolean
    Dim systeem                             As cls_systeem
    Dim ronde                               As Integer
    
    If status.stap = 1 And status.ronde = 1 Then
        knp_achteruit.Enabled = False
    Else
        knp_achteruit.Enabled = True
    End If

    For stap_nummer = 1 To 6
        Me.lbl_stap(stap_nummer).BackStyle = 0
    Next
    Me.lbl_stap(status.stap).BackStyle = 1
    Me.lbl_stap(status.stap).BackColor = 65280
    Me.lbl_ronde_nummer = status.ronde
    
    If status.stap = 4 Then
        Me.enable_toevoegen_systeem
    Else
        Me.disable_toevoegen_systeem
    End If

    Call subcpt_ui.srvc_bereken_marktaandeel_speler(marktaandeel_speler())
    Call subcpt_ui.srvc_bereken_score_volgorde(marktaandeel_speler(), score_volgorde())
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        Me.tb_marktaandeel_speler(score_volgorde(speler_nummer)).Text = _
            CStr(CInt(100 * marktaandeel_speler(speler_nummer)))
        Me.tb_naam_speler(score_volgorde(speler_nummer)).Text = _
            tbl_speler.rij(CLng(speler_nummer)).speler_naam
        Me.im_pion_speler(score_volgorde(speler_nummer)).Picture = _
            pion.im_pion(tbl_speler.rij(CLng(speler_nummer)).pion_nummer).Picture
    Next
    
    For volg_nummer = 0 To aantal_vakken * aantal_teams - 1
        Me.im_nieuw(volg_nummer).Picture = Nothing
        Me.im_bestaand(volg_nummer).Picture = Nothing
        Me.tb_marktaandeel_systeem(volg_nummer).Visible = False
    Next
    
    ronde = status.ronde
    If ronde > 1 And status.stap < 3 Then ronde = ronde - 1
    Set huidig_speelbord = tbl_speelbord.rij(CLng(ronde))
    For vak_nummer = 0 To aantal_vakken - 1
        aantal_systemen = 0
        For team_nummer = 1 To aantal_teams
            Set systeem = huidig_speelbord.systeem(vak_nummer, team_nummer)
            If systeem.aanwezig Then
                systeem_is_nieuw = False
                aantal_systemen = aantal_systemen + 1
                volg_nummer = 4 * (vak_nummer + 1) - aantal_systemen
                If ronde = 1 Then
                    systeem_is_nieuw = True
                ElseIf Not tbl_speelbord.rij(CLng(ronde - 1)).systeem(vak_nummer, team_nummer).aanwezig Then
                    systeem_is_nieuw = True
                End If
                If systeem_is_nieuw Then
                    Me.im_nieuw(volg_nummer).Picture = _
                        pion.im_pion(tbl_speler.rij(CLng(systeem.speler_nummer)).pion_nummer).Picture
                Else
                    Me.im_bestaand(volg_nummer).Picture = _
                        pion.im_pion(tbl_speler.rij(CLng(systeem.speler_nummer)).pion_nummer).Picture
                End If
                Me.tb_marktaandeel_systeem(volg_nummer).Text = _
                    CStr(CInt(100 * systeem.marktaandeel))
                Me.tb_marktaandeel_systeem(volg_nummer).Visible = True
            End If
        Next
    Next
End Sub

Public Sub disable_toevoegen_systeem()
    For vak_nummer = 0 To aantal_vakken - 1
        Me.knp_voeg_systeem_toe(vak_nummer).Enabled = False
    Next
End Sub

Public Sub enable_toevoegen_systeem()
    For vak_nummer = 0 To aantal_vakken - 1
        Me.knp_voeg_systeem_toe(vak_nummer).Enabled = True
    Next
End Sub

Private Sub knp_achteruit_Click()
    If status.vak_nummer = 0 Then Call cpt_ui.srvc_achteruit
End Sub

Private Sub knp_vooruit_Click()
    If status.vak_nummer = 0 Then Call cpt_ui.srvc_vooruit
End Sub

Private Sub knp_voeg_systeem_toe_Click(vak_nummer As Integer)
    Dim voeg_systeem_toe As New frm_voeg_systeem_toe
    
    If status.vak_nummer = 0 Then
        status.vak_nummer = vak_nummer
        voeg_systeem_toe.Show
    End If
End Sub


[[CLS_CPT_UI]]

Public voeg_speler_toe As New frm_voeg_speler_toe

Public Sub srvc_start_nieuw_spel()
    Call subcpt_ui.srvc_initialiseer_spel
    Call voeg_speler_toe.Show
End Sub

Public Sub srvc_voeg_speler_toe(ByRef speler() As String)
    For speler_nummer = 1 To aantal_spelers
        If speler(speler_nummer) <> "" Then
            Call subcpt_ui.srvc_voeg_speler_toe( _
                speler(speler_nummer), _
                (speler_nummer + 3) \ 4, _
                speler_nummer)
        End If
    Next
    Call speelbord.initialiseer
    Call speelbord.refresh_me
End Sub

Public Sub srvc_achteruit()
    Select Case status.stap
        Case 1
            Call subcpt_ui.srvc_verwijder_huidig_speelbord
            status.ronde = status.ronde - 1
        Case 4
            Call subcpt_ui.srvc_naar_vorige_configuratie
        Case 5
            Call subcpt_ui.srvc_bereken_marktaandeel_per_systeem("achteruit")
    End Select
    status.stap = 6 + ((status.stap - 7) Mod 6)
    Call speelbord.refresh_me
End Sub

Public Sub srvc_vooruit()
    status.stap = status.stap Mod 6 + 1
    Select Case status.stap
        Case 1
            status.ronde = status.ronde + 1
            Call subcpt_ui.srvc_voeg_speelbord_toe
        Case 5
            Call subcpt_ui.srvc_bereken_marktaandeel_per_systeem("vooruit")
    End Select
    Call speelbord.refresh_me
End Sub

Public Sub srvc_voeg_systeem_toe( _
    ByVal vak_nummer As Integer, _
    ByRef speler() As Integer)
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        If speler(speler_nummer) = 1 Then _
            Call subcpt_ui.srvc_voeg_systeem_toe(speler_nummer, vak_nummer)
        If speler(speler_nummer) = -1 Then _
            Call subcpt_ui.srvc_verwijder_systeem(speler_nummer, vak_nummer)
    Next
    Call speelbord.refresh_me
End Sub


[[CLS_SUBCPT_UI]]

Public Sub srvc_initialiseer_spel()
    status.ronde = 1
    status.stap = 1
    Call srvc_voeg_speelbord_toe
End Sub

Public Sub srvc_voeg_speler_toe( _
    ByVal speler_naam As String, _
    ByVal team_nummer As Integer, _
    ByVal pion_nummer As Integer)
    Dim nieuw_rij_speler As New cls_rij_speler

    nieuw_rij_speler.verwijderd = False
    nieuw_rij_speler.speler_naam = speler_naam
    nieuw_rij_speler.team_nummer = team_nummer
    nieuw_rij_speler.pion_nummer = pion_nummer
    Call tbl_speler.voeg_toe(nieuw_rij_speler)
End Sub

Public Sub srvc_speler_heeft_systeem_in_vak( _
    ByVal vak_nummer As Integer, _
    ByRef speler_heeft_systeem_in_vak() As Boolean)
    Dim systeem As cls_systeem

    For team_nummer = 1 To aantal_teams
        Set systeem = tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer)
        If systeem.aanwezig Then
            speler_heeft_systeem_in_vak(systeem.speler_nummer) = True
        Else
            speler_heeft_systeem_in_vak(systeem.speler_nummer) = False
        End If
    Next
End Sub

Public Sub srvc_voeg_speelbord_toe()
    Dim nieuw_speelbord As New cls_rij_speelbord
    Dim oud_speelbord As cls_rij_speelbord
    
    For vak_nummer = 0 To aantal_vakken - 1
        For team_nummer = 1 To aantal_teams
            nieuw_speelbord.systeem(vak_nummer, team_nummer) = New cls_systeem
            nieuw_speelbord.systeem(vak_nummer, team_nummer).aanwezig = False
            nieuw_speelbord.systeem(vak_nummer, team_nummer).marktaandeel = 0
            nieuw_speelbord.systeem(vak_nummer, team_nummer).speler_nummer = 0
        Next
    Next
    If status.ronde > 1 Then
        Set oud_speelbord = tbl_speelbord.rij(CLng(status.ronde - 1))
        For vak_nummer = 0 To aantal_vakken - 1
            For team_nummer = 1 To aantal_teams
                nieuw_speelbord.systeem(vak_nummer, team_nummer).aanwezig = _
                    oud_speelbord.systeem(vak_nummer, team_nummer).aanwezig
                nieuw_speelbord.systeem(vak_nummer, team_nummer).marktaandeel = _
                    oud_speelbord.systeem(vak_nummer, team_nummer).marktaandeel
                nieuw_speelbord.systeem(vak_nummer, team_nummer).speler_nummer = _
                    oud_speelbord.systeem(vak_nummer, team_nummer).speler_nummer
            Next
        Next
    End If
    
    Call tbl_speelbord.voeg_toe(nieuw_speelbord)
End Sub

Public Sub srvc_voeg_systeem_toe( _
    ByVal speler_nummer As Integer, _
    ByVal vak_nummer As Integer)
    Dim systeem As cls_systeem
    
    Set systeem = tbl_speelbord.rij(status.ronde).systeem(vak_nummer, tbl_speler.rij(speler_nummer).team_nummer)
    systeem.aanwezig = True
    systeem.speler_nummer = speler_nummer
    systeem.marktaandeel = 0
End Sub

Public Sub srvc_verwijder_systeem( _
    ByVal speler_nummer As Integer, _
    ByVal vak_nummer As Integer)
    
    tbl_speelbord.rij(status.ronde).systeem(vak_nummer, tbl_speler.rij(speler_nummer).team_nummer).aanwezig = False
End Sub

Public Sub srvc_verwijder_huidig_speelbord()
    Call tbl_speelbord.verwijder_laatste_rij
End Sub

Public Sub srvc_naar_vorige_configuratie()
    Call tbl_speelbord.verwijder_laatste_rij
    Call srvc_voeg_speelbord_toe
End Sub

Public Sub srvc_bereken_marktaandeel_per_systeem(ByVal richting As String)
    Dim systeem                                          As cls_systeem
    Dim team_nummer                                      As Integer
    Dim vak_nummer                                       As Integer
    Dim nieuw_per_team(aantal_teams)                     As Integer
    Dim totaal_per_team(aantal_teams)                    As Integer
    Dim totaal_per_vak(aantal_vakken)                    As Integer
    Dim gewicht_per_systeem(aantal_vakken, aantal_teams) As Integer
    Dim gewicht_nieuw(aantal_vakken)                     As Integer
    Dim gewicht_bestaand(aantal_vakken)                  As Integer
    Dim totaal_oude_marktaandelen(aantal_vakken)         As Double
    Dim systeem_is_nieuw                                 As Boolean

    For vak_nummer = 0 To aantal_vakken - 1
        For team_nummer = 1 To aantal_teams
            If tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer).aanwezig Then
                totaal_per_team(team_nummer) = totaal_per_team(team_nummer) + 1
                If status.ronde > 1 Then
                    If Not tbl_speelbord.rij(status.ronde - 1).systeem(vak_nummer, team_nummer).aanwezig Then _
                        nieuw_per_team(team_nummer) = nieuw_per_team(team_nummer) + 1
                End If
            End If
            If status.ronde > 1 Then
                If Not tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer).aanwezig And _
                    tbl_speelbord.rij(status.ronde - 1).systeem(vak_nummer, team_nummer).aanwezig Then
                        nieuw_per_team(team_nummer) = nieuw_per_team(team_nummer) - 1
                        totaal_oude_marktaandelen(vak_nummer) = _
                            totaal_oude_marktaandelen(vak_nummer) + _
                            tbl_speelbord.rij(status.ronde - 1).systeem(vak_nummer, team_nummer).marktaandeel
                End If
            End If
        Next
    Next

    For vak_nummer = 0 To aantal_vakken - 1
        totaal_oude_marktaandelen(vak_nummer) = _
            1 - totaal_oude_marktaandelen(vak_nummer)
        If totaal_oude_marktaandelen(vak_nummer) = 0 Then _
            totaal_oude_marktaandelen(vak_nummer) = 1
    Next

    For vak_nummer = 0 To aantal_vakken - 1
        For team_nummer = 1 To aantal_teams
            systeem_is_nieuw = False
            If tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer).aanwezig Then
                If status.ronde = 1 Then
                    systeem_is_nieuw = True
                Else
                    If Not tbl_speelbord.rij(status.ronde - 1).systeem(vak_nummer, team_nummer).aanwezig Then _
                        systeem_is_nieuw = True
                End If
                If systeem_is_nieuw Then
                    gewicht_per_systeem(vak_nummer, team_nummer) = _
                        totaal_per_team(team_nummer)
                Else
                    gewicht_per_systeem(vak_nummer, team_nummer) = _
                        nieuw_per_team(team_nummer)
                End If
            End If
        Next
    Next

    For vak_nummer = 0 To aantal_vakken - 1
        For team_nummer = 1 To aantal_teams
            If tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer).aanwezig Then
                gewicht_nieuw(vak_nummer) = _
                    gewicht_nieuw(vak_nummer) + gewicht_per_systeem(vak_nummer, team_nummer)
                totaal_per_vak(vak_nummer) = _
                    totaal_per_vak(vak_nummer) + totaal_per_team(team_nummer)
            End If
        Next
    Next

    For vak_nummer = 0 To aantal_vakken - 1
        gewicht_bestaand(vak_nummer) = _
            totaal_per_vak(vak_nummer) - gewicht_nieuw(vak_nummer)
    Next
    
    Select Case richting
        Case "vooruit"
            For vak_nummer = 0 To aantal_vakken - 1
                For team_nummer = 1 To aantal_teams
                    Set systeem = tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer)
                    If systeem.aanwezig Then
                        systeem.marktaandeel = _
                          ( _
                            2 * gewicht_bestaand(vak_nummer) * _
                            systeem.marktaandeel + _
                            gewicht_per_systeem(vak_nummer, team_nummer) * _
                            totaal_oude_marktaandelen(vak_nummer) _
                          ) / _
                          ( _
                            ( _
                              2 * gewicht_bestaand(vak_nummer) + _
                              gewicht_nieuw(vak_nummer) _
                            ) * _
                            totaal_oude_marktaandelen(vak_nummer) _
                          )
                    End If
                Next
            Next
        Case "achteruit"
            For vak_nummer = 0 To aantal_vakken - 1
                For team_nummer = 1 To aantal_teams
                    Set systeem = tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer)
                    If systeem.aanwezig Then
                        If gewicht_bestaand(vak_nummer) > 0 Then
                            systeem.marktaandeel = _
                               ( _
                                 systeem.marktaandeel * _
                                 ( _
                                   2 * gewicht_bestaand(vak_nummer) + _
                                   gewicht_nieuw(vak_nummer) _
                                 ) - _
                                 gewicht_per_systeem(vak_nummer, team_nummer) _
                               ) * _
                               totaal_oude_marktaandelen(vak_nummer) / _
                               ( _
                                 2 * gewicht_bestaand(vak_nummer) _
                               )
                        Else
                            systeem.marktaandeel = 0
                        End If
                    End If
                Next
            Next
    End Select
End Sub

Public Sub srvc_bereken_marktaandeel_speler(ByRef marktaandeel_speler() As Double)
    Dim systeem As cls_systeem
    Dim speler_nummer As Integer

    For vak_nummer = 0 To aantal_vakken - 1
        For team_nummer = 1 To aantal_teams
            Set systeem = tbl_speelbord.rij(status.ronde).systeem(vak_nummer, team_nummer)
            If systeem.aanwezig Then
                speler_nummer = systeem.speler_nummer
                marktaandeel_speler(speler_nummer) = _
                    marktaandeel_speler(speler_nummer) + systeem.marktaandeel
            End If
        Next
    Next
End Sub

Public Sub srvc_bereken_score_volgorde( _
    ByRef marktaandeel_speler() As Double, _
    ByRef speler_volgorde() As Integer)
    Dim locaal_marktaandeel(aantal_spelers) As Double
    Dim inverse_volgorde(aantal_spelers) As Integer
    
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        locaal_marktaandeel(speler_nummer) = marktaandeel_speler(speler_nummer)
    Next
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        inverse_volgorde(speler_nummer) = speler_nummer
    Next
    Call bubble(locaal_marktaandeel(), inverse_volgorde(), 1)
    For speler_nummer = 1 To tbl_speler.aantal_rijen
        speler_volgorde(inverse_volgorde(speler_nummer)) = speler_nummer
    Next
End Sub

Private Sub bubble(ByRef locaal_marktaandeel() As Double, _
    ByRef inverse_volgorde() As Integer, _
    ByRef speler_nummer As Integer)
    Dim temp_marktaandeel As Double
    Dim temp_nummer As Integer
    
    If locaal_marktaandeel(speler_nummer) >= locaal_marktaandeel(speler_nummer + 1) Then
        speler_nummer = speler_nummer + 1
    Else
        temp_marktaandeel = locaal_marktaandeel(speler_nummer)
        locaal_marktaandeel(speler_nummer) = locaal_marktaandeel(speler_nummer + 1)
        locaal_marktaandeel(speler_nummer + 1) = temp_marktaandeel
        temp_volgorde = inverse_volgorde(speler_nummer)
        inverse_volgorde(speler_nummer) = inverse_volgorde(speler_nummer + 1)
        inverse_volgorde(speler_nummer + 1) = temp_volgorde
        If speler_nummer > 1 Then speler_nummer = speler_nummer - 1
    End If
    If speler_nummer < tbl_speler.aantal_rijen Then _
        Call bubble(locaal_marktaandeel(), inverse_volgorde(), speler_nummer)
End Sub


[[CLS_STATUS]]

Private ronde_      As Integer
Private stap_       As Integer
Private vak_nummer_ As Integer

Public Property Get ronde() As Integer
    ronde = ronde_
End Property

Public Property Let ronde(ByVal let_ronde As Integer)
    ronde_ = let_ronde
End Property

Public Property Get stap() As Integer
    stap = stap_
End Property

Public Property Let stap(ByVal let_stap As Integer)
    stap_ = let_stap
End Property

Public Property Get vak_nummer() As Integer
    vak_nummer = vak_nummer_
End Property

Public Property Let vak_nummer(ByVal let_vak_nummer As Integer)
    vak_nummer_ = let_vak_nummer
End Property


[[CLS_TBL_SPELER]]

Private rijen()       As cls_rij_speler
Private aantal_rijen_ As Integer

Public Sub voeg_toe(rij_voeg_toe As cls_rij_speler)
    aantal_rijen_ = aantal_rijen_ + 1
    ReDim Preserve rijen(aantal_rijen_)
    Set rijen(aantal_rijen_) = rij_voeg_toe
End Sub

Public Sub verwijder(rij_nummer As Integer)
    rijen(rij_nummer).verwijderd = True
End Sub

Public Property Get rij(rij_nummer As Integer) As cls_rij_speler
    Set rij = rijen(rij_nummer)
End Property

Public Property Get aantal_rijen() As Integer
    aantal_rijen = aantal_rijen_
End Property


[[CLS_TBL_SPEELBORD]]

Private rijen()         As cls_rij_speelbord
Private aantal_rijen_   As Integer

Public Sub voeg_toe(rij_voeg_toe As cls_rij_speelbord)
    aantal_rijen_ = aantal_rijen_ + 1
    ReDim Preserve rijen(aantal_rijen_)
    Set rijen(aantal_rijen_) = rij_voeg_toe
End Sub

Public Sub verwijder_laatste_rij()
    Set rijen(aantal_rijen_) = Nothing
    aantal_rijen_ = aantal_rijen_ - 1
    ReDim Preserve rijen(aantal_rijen_)
End Sub

Public Property Get rij(rij_nummer As Integer) As cls_rij_speelbord
    Set rij = rijen(rij_nummer)
End Property

Public Property Get aantal_rijen() As Integer
    aantal_rijen = aantal_rijen_
End Property


[[CLS_RIJ_SPELER]]

Private verwijderd_  As Boolean ' wordt momenteel niet gebruikt
Private speler_naam_ As String
Private team_nummer_ As Integer
Private pion_nummer_ As Integer

Public Property Get verwijderd() As Boolean
    verwijderd = verwijderd_
End Property

Public Property Let verwijderd(ByVal let_verwijderd As Boolean)
    verwijderd_ = let_verwijderd
End Property

Public Property Get speler_naam() As String
    speler_naam = speler_naam_
End Property

Public Property Let speler_naam(ByVal let_speler_naam As String)
    speler_naam_ = let_speler_naam
End Property

Public Property Get team_nummer() As Integer
    team_nummer = team_nummer_
End Property

Public Property Let team_nummer(ByVal let_team_nummer As Integer)
    team_nummer_ = let_team_nummer
End Property

Public Property Get pion_nummer() As Integer
    pion_nummer = pion_nummer_
End Property

Public Property Let pion_nummer(ByVal let_pion_nummer As Integer)
    pion_nummer_ = let_pion_nummer
End Property


[[CLS_RIJ_SPEELBORD]]

Private systeem_(aantal_vakken - 1, aantal_teams) As cls_systeem

Public Property Get systeem( _
    ByVal vak_nummer As Integer, _
    ByVal team_nummer As Integer) As cls_systeem
    Set systeem = systeem_(vak_nummer, team_nummer)
End Property

Public Property Let systeem( _
    ByVal vak_nummer As Integer, _
    ByVal team_nummer As Integer, _
    ByRef let_systeem As cls_systeem)
    Set systeem_(vak_nummer, team_nummer) = let_systeem
End Property


[[CLS_SYSTEEM]]

Private aanwezig_       As Boolean
Private speler_nummer_  As Integer
Private marktaandeel_   As Double

Public Property Get aanwezig() As Boolean
    aanwezig = aanwezig_
End Property

Public Property Let aanwezig(ByVal let_aanwezig As Boolean)
    aanwezig_ = let_aanwezig
End Property

Public Property Get speler_nummer() As Integer
    speler_nummer = speler_nummer_
End Property

Public Property Let speler_nummer(ByVal let_speler_nummer As Integer)
    speler_nummer_ = let_speler_nummer
End Property

Public Property Get marktaandeel() As Double
    marktaandeel = marktaandeel_
End Property

Public Property Let marktaandeel(ByVal let_marktaandeel As Double)
    marktaandeel_ = let_marktaandeel
End Property